83f8f59569
'xft-config' is deprecated (http://lists.freedesktop.org/archives/xorg-devel/2010-March/006750.html) and does not exist anymore on 'bleeding edge' versions (gentoo). 'pkg-config' is the new way of doing things. 'pkg-config --libs xft' does only report the libs needed and the linker finds out other dependencies on its own. currently, 'pkg-config' (version 0.25) reports only '-lXft'. if the user wants for example LDFLAGS="-fuse-ld=gold --no-add-needed" then all the needed libs must be produced, otherwise linkage fails. at the moment it seems that fluxbox calls 'XftMatrixRotate()' and 'XftPatternAddMatrix()' which both seems to trigger the need for 'fontconfig': undefined reference to 'FcMatrixRotate' undefined reference to 'FcPatternAddMatrix' is 'pkg-config --libs xft' reporting to few libs? in comparison to 'xft-config --libs' for sure. bug? feature? i am not sure. there are several ways to address this issue: * append the needed libs manually via LIBS or LDFLAGS env LIBS="-lfontconfig" ./configure * change build-system of fluxbox to do something like pkg-config --print-requires-private 'xft' 2> /dev/null || echo xft)` (pkg-config version < 0.2x does not have --print-requires-private, which then leads to not print out all libs needed, which would then require a fallback to xft-config since an older system anyways, evidence is old pkg-config) * changing build-system of fluxbox to use something like: pkg-config --static --libs xft (which reports really all libs, even more than actually needed, check out http://osdir.com/ml/debian-bugs-closed/2011-01/msg01112.html) * fix 'pkg-config' (or the related xft.pc) to report '-lXft -lfontconfig' (not our code, but preferable) * use 'pkg-config --libs xft fontconfig' since we know that calling the xft functions requires linking against 'fontconfig' as well: pkg-config --libs xft fontconfig which is what we use to get rid of the build-errors
231 lines
9.1 KiB
Text
231 lines
9.1 KiB
Text
dnl @synopsis AC_PATH_GENERIC(LIBRARY [, MINIMUM-VERSION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
|
dnl
|
|
dnl Runs a LIBRARY-config script and defines LIBRARY_CFLAGS and LIBRARY_LIBS
|
|
dnl
|
|
dnl The script must support `--cflags' and `--libs' args.
|
|
dnl If MINIMUM-VERSION is specified, the script must also support the
|
|
dnl `--version' arg.
|
|
dnl If the `--with-library-[exec-]prefix' arguments to ./configure are given,
|
|
dnl it must also support `--prefix' and `--exec-prefix'.
|
|
dnl (In other words, it must be like gtk-config.)
|
|
dnl
|
|
dnl For example:
|
|
dnl
|
|
dnl AC_PATH_GENERIC(Foo, 1.0.0)
|
|
dnl
|
|
dnl would run `foo-config --version' and check that it is at least 1.0.0
|
|
dnl
|
|
dnl If so, the following would then be defined:
|
|
dnl
|
|
dnl FOO_CFLAGS to `foo-config --cflags`
|
|
dnl FOO_LIBS to `foo-config --libs`
|
|
dnl
|
|
dnl At present there is no support for additional "MODULES" (see AM_PATH_GTK)
|
|
dnl (shamelessly stolen from gtk.m4 and then hacked around a fair amount)
|
|
dnl
|
|
dnl @author Angus Lees <gusl@cse.unsw.edu.au>
|
|
dnl @version $Id: ac_path_generic.m4,v 1.1.1.1 2001/07/26 00:46:28 guidod Exp $
|
|
|
|
AC_DEFUN([AC_PATH_GENERIC],
|
|
[dnl
|
|
dnl we're going to need uppercase, lowercase and user-friendly versions of the
|
|
dnl string `LIBRARY'
|
|
pushdef([UP], translit([$1], [a-z], [A-Z]))dnl
|
|
pushdef([DOWN], translit([$1], [A-Z], [a-z]))dnl
|
|
|
|
dnl
|
|
dnl Get the cflags and libraries from the LIBRARY-config script
|
|
dnl
|
|
AC_ARG_WITH(DOWN-prefix,[ --with-]DOWN[-prefix=PFX Prefix where $1 is installed (optional)],
|
|
DOWN[]_config_prefix="$withval", DOWN[]_config_prefix="")
|
|
AC_ARG_WITH(DOWN-exec-prefix,[ --with-]DOWN[-exec-prefix=PFX Exec prefix where $1 is installed (optional)],
|
|
DOWN[]_config_exec_prefix="$withval", DOWN[]_config_exec_prefix="")
|
|
|
|
if test x$DOWN[]_config_exec_prefix != x ; then
|
|
DOWN[]_config_args="$DOWN[]_config_args --exec-prefix=$DOWN[]_config_exec_prefix"
|
|
if test x${UP[]_CONFIG+set} != xset ; then
|
|
UP[]_CONFIG=$DOWN[]_config_exec_prefix/bin/DOWN-config
|
|
fi
|
|
fi
|
|
if test x$DOWN[]_config_prefix != x ; then
|
|
DOWN[]_config_args="$DOWN[]_config_args --prefix=$DOWN[]_config_prefix"
|
|
if test x${UP[]_CONFIG+set} != xset ; then
|
|
UP[]_CONFIG=$DOWN[]_config_prefix/bin/DOWN-config
|
|
fi
|
|
fi
|
|
|
|
AC_PATH_PROG(UP[]_CONFIG, DOWN-config, no)
|
|
ifelse([$2], ,
|
|
AC_MSG_CHECKING(for $1),
|
|
AC_MSG_CHECKING(for $1 - version >= $2)
|
|
)
|
|
no_[]DOWN=""
|
|
if test "$UP[]_CONFIG" = "no" ; then
|
|
no_[]DOWN=yes
|
|
else
|
|
UP[]_CFLAGS="`$UP[]_CONFIG $DOWN[]_config_args --cflags`"
|
|
UP[]_LIBS="`$UP[]_CONFIG $DOWN[]_config_args --libs`"
|
|
ifelse([$2], , ,[
|
|
DOWN[]_config_major_version=`$UP[]_CONFIG $DOWN[]_config_args \
|
|
--version | sed 's/[[^0-9]]*\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
|
|
DOWN[]_config_minor_version=`$UP[]_CONFIG $DOWN[]_config_args \
|
|
--version | sed 's/[[^0-9]]*\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
|
|
DOWN[]_config_micro_version=`$UP[]_CONFIG $DOWN[]_config_args \
|
|
--version | sed 's/[[^0-9]]*\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
|
|
DOWN[]_wanted_major_version="regexp($2, [\<\([0-9]*\)], [\1])"
|
|
DOWN[]_wanted_minor_version="regexp($2, [\<\([0-9]*\)\.\([0-9]*\)], [\2])"
|
|
DOWN[]_wanted_micro_version="regexp($2, [\<\([0-9]*\).\([0-9]*\).\([0-9]*\)], [\3])"
|
|
|
|
# Compare wanted version to what config script returned.
|
|
# If I knew what library was being run, i'd probably also compile
|
|
# a test program at this point (which also extracted and tested
|
|
# the version in some library-specific way)
|
|
if test "$DOWN[]_config_major_version" -lt \
|
|
"$DOWN[]_wanted_major_version" \
|
|
-o \( "$DOWN[]_config_major_version" -eq \
|
|
"$DOWN[]_wanted_major_version" \
|
|
-a "$DOWN[]_config_minor_version" -lt \
|
|
"$DOWN[]_wanted_minor_version" \) \
|
|
-o \( "$DOWN[]_config_major_version" -eq \
|
|
"$DOWN[]_wanted_major_version" \
|
|
-a "$DOWN[]_config_minor_version" -eq \
|
|
"$DOWN[]_wanted_minor_version" \
|
|
-a "$DOWN[]_config_micro_version" -lt \
|
|
"$DOWN[]_wanted_micro_version" \) ; then
|
|
# older version found
|
|
no_[]DOWN=yes
|
|
echo -n "*** An old version of $1 "
|
|
echo -n "($DOWN[]_config_major_version"
|
|
echo -n ".$DOWN[]_config_minor_version"
|
|
echo ".$DOWN[]_config_micro_version) was found."
|
|
echo -n "*** You need a version of $1 newer than "
|
|
echo -n "$DOWN[]_wanted_major_version"
|
|
echo -n ".$DOWN[]_wanted_minor_version"
|
|
echo ".$DOWN[]_wanted_micro_version."
|
|
echo "***"
|
|
echo "*** If you have already installed a sufficiently new version, this error"
|
|
echo "*** probably means that the wrong copy of the DOWN-config shell script is"
|
|
echo "*** being found. The easiest way to fix this is to remove the old version"
|
|
echo "*** of $1, but you can also set the UP[]_CONFIG environment to point to the"
|
|
echo "*** correct copy of DOWN-config. (In this case, you will have to"
|
|
echo "*** modify your LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf"
|
|
echo "*** so that the correct libraries are found at run-time)"
|
|
fi
|
|
])
|
|
fi
|
|
if test "x$no_[]DOWN" = x ; then
|
|
AC_MSG_RESULT(yes)
|
|
ifelse([$3], , :, [$3])
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
if test "$UP[]_CONFIG" = "no" ; then
|
|
echo "*** The DOWN-config script installed by $1 could not be found"
|
|
echo "*** If $1 was installed in PREFIX, make sure PREFIX/bin is in"
|
|
echo "*** your path, or set the UP[]_CONFIG environment variable to the"
|
|
echo "*** full path to DOWN-config."
|
|
fi
|
|
UP[]_CFLAGS=""
|
|
UP[]_LIBS=""
|
|
ifelse([$4], , :, [$4])
|
|
fi
|
|
AC_SUBST(UP[]_CFLAGS)
|
|
AC_SUBST(UP[]_LIBS)
|
|
|
|
popdef([UP])
|
|
popdef([DOWN])
|
|
])
|
|
# xft.m4
|
|
# Copyright (c) 2002 Henrik Kinnunen (fluxgen at linuxmail.org)
|
|
|
|
# Permission is hereby granted, free of charge, to any person obtaining a
|
|
# copy of this software and associated documentation files (the "Software"),
|
|
# to deal in the Software without restriction, including without limitation
|
|
# the rights to use, copy, modify, merge, publish, distribute, sublicense,
|
|
# and/or sell copies of the Software, and to permit persons to whom the
|
|
# Software is furnished to do so, subject to the following conditions:
|
|
|
|
# The above copyright notice and this permission notice shall be included in
|
|
# all copies or substantial portions of the Software.
|
|
|
|
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
|
|
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
|
|
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
|
|
# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
|
|
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
|
|
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
|
|
# DEALINGS IN THE SOFTWARE.
|
|
|
|
# AM_PATH_XFT1([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
|
AC_DEFUN([AM_PATH_XFT1],
|
|
[
|
|
AC_CHECK_LIB(Xft, XftFontOpen,
|
|
XFT_LIBS="-lXft"
|
|
[$1],
|
|
[$2]
|
|
)
|
|
])
|
|
|
|
# AM_PATH_XFT2([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
|
AC_DEFUN([AM_PATH_XFT2],
|
|
[
|
|
if test x$pkg_exec_prefix != x ; then
|
|
xft_args="$xft_args --exec-prefix=$pkg_exec_prefix"
|
|
if test x${PKG_CONFIG+set} != xset ; then
|
|
PKG_CONFIG=$pkg_exec_prefix/bin/pkg-config
|
|
fi
|
|
fi
|
|
|
|
if test x$xft_prefix != x ; then
|
|
xft_args="$xft_args --prefix=$xft_prefix"
|
|
if test x${PKG_CONFIG+set} != xset ; then
|
|
PKG_CONFIG=$xft_prefix/bin/pkg-config
|
|
fi
|
|
fi
|
|
|
|
AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
|
|
if test "x$PKG_CONFIG" = "xno" ; then
|
|
ifelse([$2], , :, [$2])
|
|
else
|
|
XFT_CFLAGS=`$PKG_CONFIG $xftconf_args --cflags xft fontconfig`
|
|
XFT_LIBS=`$PKG_CONFIG $xftconf_args --libs xft fontconfig`
|
|
ifelse([$1], , :, [$1])
|
|
fi
|
|
])
|
|
|
|
# AM_PATH_XFT(default-value, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
|
|
# Test for Xft, and define XFT_CFLAGS and XFT_LIBS
|
|
AC_DEFUN([AM_PATH_XFT],
|
|
[
|
|
AC_ARG_WITH(xft-prefix,[ --with-xft-prefix=path Prefix where Xft is installed (optional)],
|
|
xft_prefix="$withval", xft_prefix="")
|
|
AC_ARG_WITH(pkg-exec-prefix,[ --with-pkg-exec-prefix=path Exec prefix where pkg-config is installed (optional)],
|
|
pkg_exec_prefix="$withval", pkg_exec_prefix="")
|
|
AC_ARG_ENABLE(xft, [ --enable-xft Xft (antialias) support (default=$1)],
|
|
if test "x$enableval" = "xyes"; then
|
|
TRY_XFT=yes
|
|
else
|
|
TRY_XFT=no
|
|
fi
|
|
,
|
|
TRY_XFT=$1
|
|
)
|
|
|
|
if test "x$TRY_XFT" = "xyes"; then
|
|
AC_MSG_RESULT(yes)
|
|
AM_PATH_XFT2(
|
|
[$2],
|
|
# xft2 failed: try xft1
|
|
AM_PATH_XFT1(
|
|
[$2],
|
|
[$3]
|
|
AC_MSG_RESULT([Cant find Xft libraries! Disabling Xft]))
|
|
)
|
|
else
|
|
AC_MSG_RESULT(no)
|
|
[$3]
|
|
fi
|
|
|
|
CFLAGS="$CFLAGS $XFT_CFLAGS"
|
|
CXXFLAGS="$CXXFLAGS $XFT_CFLAGS"
|
|
LIBS="$LIBS $XFT_LIBS"
|
|
])
|